홍환민 홈페이지 * 사용자 참여란

USB 드라이브 안전하게 제거하기.

과니 — Wed, 14 May 2008 15:49:48 +0900

// 과니입니다
// 2008.05.14 오늘의 팁입니다.
// 일주일전 부친상으로 인해 회사를 일주일 쉬었더니 출근하기 정말 힘들었습니다...
// 게을러진 맘을 잡고 팁을 올립니다.
// 오늘의 팁은 USB 드라이브를 안전하게 제거하는 방법입니다.
// 복잡하게 하기보단 최대한 단순하게 하기 위해 드라이브는 임의의 'E:' 드라이브로 정의하였습니다.

procedure TForm1.Button1Click(Sender: TObject);
const
    IOCTL_STORAGE_EJECT_MEDIA = $2D4808;
    COMPLETE_MESSAGE = '드라이브를 안전하게 제거하실 수 있습니다.';
var
    hDevice : THandle;
    dwByteReturned : DWORD;
begin
    hDevice := CreateFile(PChar('\\.\E:'), GENERIC_READ or GENERIC_WRITE,
                         FILE_SHARE_READ or FILE_SHARE_WRITE,
                         nil, OPEN_EXISTING, 0, 0);

if hDevice = INVALID_HANDLE_VALUE then Exit;

// 디스크 제거
DeviceIoControl(hDevice, IOCTL_STORAGE_EJECT_MEDIA, nil, 0, nil, 0, dwByteReturned, nil);

CloseHandle(hDevice);

Application.MessageBox(PChar(COMPLETE_MESSAGE), 'Information', MB_ICONINFORMATION);
end;

라자루스 관련 사용자 컨트롤

이정훈 — Wed, 14 May 2008 09:49:37 +0900

홍환민 님이 라자루스에 대해 델마당 쓰신 글을 보고 관심있어서 어제 다운 받고

윈도우xp 에서 몇가지 구동해 보았습니다

실력이 미쳔하여 팁같은거라고 올려놓을 것도 없습니다 그냥 라자루스 체험기 정도로만

봐주세요...

사용자 컨트롤을 한번 만들어 보고자 아무 의미 없이 클릭하면 이미지가 변경되는

컨트롤(?)을 만들어 보았습니다...

상속받은건 TCustomControl ....라자루스는 클래스 구조와 이름이 델파이와 거의 동일 한것 같습니다

그냥 클릭하면 이미지가 계속 바뀌는 단순한

버튼입니다 (컴포넌트라기 보단 클래스라고 해야 되지 않을까 싶네요...)

델파이에서 컴포넌트를 만들듯이 라자루스에서도 거의 동일하게 이용가능 한것 같습니다 (예상...)

다만 아직 컴포넌트를 인스톨하는 방법은 모르겠습니다

써보니 코드 자동완성기능이 없어 조금 불편하고 ...

그외에는 잘 모르겠지만 필요한 컴포넌트는 만들어 쓴다는 개념이면 괜찮을것 같아요

리눅스랑 호환이 가능하니깐 아무래도 멋진것 같습니다

우분투에다 깔아서 한번 해봐야 겠네요

근데 이게 라자루스에서 컴포넌트 만드는 방법인지는 모르겠습니다...그냥 컴파일 에러가 안되서

되는구나 싶기도 하네요

procedure Register;
begin
RegisterComponents('Lee', [TBitButtonDemo]);
end;

음... 혹시 고견있으시면 나눠주시길

우분투에서도 한번 해보고 ... 체험기를 올려 볼게용

누구나 다 아는 swap함수에도 비밀이 있다?!

과니 — Fri, 25 Apr 2008 15:45:04 +0900

// 과니입니다
// 2008.04.25 오늘의 팁은 누구나 다 아는 SWAP 함수입니다.
// 두 가지의 데이터를 서로 교체할 때 많이 만들어서 쓰죠.
// 일반적으로는 swap(a, b)이런식으로...
// swap도 알게 모르게 분석할 수 있는 부분이 있더라구요...ㅎㅎ

// 자 그럼 만들어 봅시다. swap 함수

// 기본형 (실수)
procedure swap(a : Integer; b : Integer);
var
    t : Integer;
begin
    t := a; // 임시 변수 t
    a := b;
    b := t;
end;

procedure TForm2.Button1Click(Sender: TObject);
var
    a, b : Integer;
begin
    a := 10;
    b := 20;

    swap(a, b);

    ShowMessage('a 변수값: ' + IntToStr(a) + ', b 변수값: ' + IntToStr(b));
end;

// 이렇게 하면 swap 함수가 완성 됩니다. 그럼 결과는 어떨까요? 잘 나올까요?
// 잘 나오겠다고 생각하셨다면 가장 중요한걸 놓쳐버린 겁니다.
// 제가 기본형 (실수)라고 적어논건 많이 실수하는 부분이라서 그렇게 적어놓았습니다.
// swap함수의 값은 그걸 호출 하는 변수의 값에 적용 되지 않기 때문에 결과적으로는
// a 변수값: 10, b변수값: 20 이 나오게 될 것 입니다.
// 이것을 가장 간단히 해결할 수 잇는 방법 swap함수 인수에 var를 붙이는 걸로 해결할 수 있습니다.

// 수정 : 1
procedure swap(var a : Integer; var b : Integer);
var
    t : Integer;
begin
    t := a; // 임시 변수 t
    a := b;
    b := t;
end;

// var은 많은 분들이 알고 계셔서 간단히만 말하자면 인자는 CallByValue와 CallByReference 로 분류 하는데
// CallByValue는 함수에 값만을 넘겨받는 거라서 함수가 끝나면 그 값은 그냥 사라져 버린다고 보시면 됩니다.
// 생략하면 CallByValue 가 됩니다.
// CallByReference 가 여기서 var에 해당되는 데 함수에 변수의 주소를 넘겨받아서 함수에서 그 값을 변경한다면
// 함수가 종료되도 그 변수가 변경된 값을 가지게 되는 것입니다.

// 여기까지 설명하려고 강좌를 쓴 건 물론 아니겠죠. var을 설명하기 위해서가 아니기 때문에
// swap 함수를 포인터로 변경해보겟습니다.

// 수정 : 2
procedure swap(a : PInteger; b : PInteger);
var
    t : Integer;
begin
    t := a^; // 임시 변수 t
    a^ := b^;
    b^ := t;
end;

// swap 함수를 포인터로 변경하였습니다. 함수의 인자가 포인터로 변경되었기 때문에 호출시에는
    Swap(@a, @b);

// 으로 해주시면 됩니다.

// 하지만 임시변수 t가 있다는게 맘에 안들기 때문에 다시 한번 더 swap 함수를 수정해 보겠습니다.

// 수정 : 3
procedure swap(a : PInteger; b : PInteger);
begin
    a^ := a^ + b^;
    b^ := a^ - b^;
    a^ := a^ - b^;
end;

// 이렇게 하면 임시변수 없이도 값이 변경되는 것을 확인 하실수가 있습니다.
// 하지만 이 함수에는 가장 위험한 요소가 있습니다. 값을 더하고 빼는 부분이 있기 때문에
// 인자의 값이 Integer형 변수의 한계에 도달하게 되는 부분에서
// 오버플로우 현상이 발생할 수 있습니다.

// 자 그럼 어떻게 하느냐

// 수정 : 4
procedure swap(a : PInteger; b : PInteger);
begin
    a^ := a^ xor b^;
    b^ := a^ xor b^;
    a^ := a^ xor b^;
end;

// 위와 같이 swap 함수를 변경해주시면 임시변수 t도 필요없고 변수의 값이 크더라도 오버플로우 현상이 없습니다.

// 누구나 알고 있는 swap이지만 그냥 지나 칠수 있는 가장 간단한 함수도 연구하면
// 더 좋은 함수로 리팩토리 될수있습니다.^^;;
//
// 이상 과니였습니다.

// 추가사항
// Lyn님이 알려주신 사항입니다.
[수정 : 2]번 함수가 [수정 : 4]함수보다 알아보기 힘들정도의 시간이긴 하지만 더 빠릅니다.ㅎ

// ------------------------------------------------------------------------
// 추가사항 : 2008-05-14
// ------------------------------------------------------------------------
위의 사항은 C/C++언어로 포팅 시
void swap(int *a, int *b)
{
    *a = *a ^ *b;
    *b = *a ^ *b;
    *a = *a ^ *b;
}

로 되고 이것은 다시 정리하면 다음과 같이 됩니다.

#define swap(a,b) (a)^=(b)^=(a)^=(b);

과정 1, 2, 3은 바로 위 define 함수로 만드는 과정을 보여주고 있는 부분으로

마지막 define은 C/C++에 해당하는 부분이라서 Delphi Swap설명에는 첨부하지 않았었습니다...ㅎ

이것을 다시 템플릿으로 선언하는 부분도 있는 데 그것은 추후에 ^^;;

레지스트리 키의 권한 설정 및 해제

과니 — Wed, 23 Apr 2008 13:34:29 +0900

// 과니입니다
// 2008.04.23 오늘의 팁은 레지스트리 키의 권한 설정입니다.
// 요즘들어 델마당의 팁이나 강좌를 올리는 분들이 없는 것 같아 보여서
// 실력없는 과니가 자꾸만 올리게됩니다.
//
// SAMPLE_REG_KEY는 전체 상수로 테스트를 시행할 레지스트리 키입니다.
// 버튼은 총 4개로 '키생성', '키삭제', '권한설정', 권한해제' 입니다.
// 키 생성을 하신 후에 권한 설정하시고 키삭제를 하려고하면 삭제가 실패될것입니다.
// 레지스트리키에 권한이 설정되어 삭제되지 않는 것이며 이것은 Regedit.exe로 실행하셔도 마찬가지 입니다.
// 하지만 키가 아닌 내용은 삭제 되더군요...ㅋㅋㅋ
//
// 다음 강좌는 뭘로 정할지 찾아보러 ㅎㄷㄷ

const
// 테스트를 시행할 레지스트리 키 상수
    SAMPLE_REG_KEY = 'Software\REGSAMPLE';

procedure TForm2.btnProtectKeyClick(Sender: TObject);
begin
    // 해당 키 권한 설정
    if ProtectKey(HKEY_LOCAL_MACHINE, SAMPLE_REG_KEY) = ERROR_SUCCESS then
        ShowMessage('권한 설정 완료')
    else
        ShowMessage('권한 설정 실패');
end;

procedure TForm2.btnUnProtectKeyClick(Sender: TObject);
begin
    // 해당 키 권한 해제
    if UnProtectKey(HKEY_LOCAL_MACHINE, SAMPLE_REG_KEY) = ERROR_SUCCESS then
        ShowMessage('권한 해제 완료')
    else
        ShowMessage('권한 해제 실패');
end;

procedure TForm2.btnCreateRegKeyClick(Sender: TObject);
var
    phkResult : hKey;
begin
    // 레지스트리 키 생성
    if RegCreateKey(HKEY_LOCAL_MACHINE, SAMPLE_REG_KEY, phkResult) = ERROR_SUCCESS then begin
        ShowMessage('생성 완료');
    end else begin
        ShowMessage('생성 오류');
    end;
end;

procedure TForm2.btnDeleteRegKeyClick(Sender: TObject);
begin
    // 레지스트리 키 삭제
    if RegDeleteKey(HKEY_LOCAL_MACHINE, SAMPLE_REG_KEY) = ERROR_SUCCESS then begin
        ShowMessage('삭제 완료');
    end else begin
        ShowMessage('삭제 오류');
    end;
end;

function OpenOrCreateKey(hKey : Cardinal; lpSubKey : String; var phkResult : hKey; fCreate : Boolean = True) : Integer;
begin
    // 레지스트리 키 검색
    if RegOpenKeyEx(hKey, PChar(lpSubKey), 0, KEY_ALL_ACCESS, phkResult) = ERROR_SUCCESS then begin
        Result := RegOpenKey(hKey, PChar(lpSubKey), phkResult);
        if Result = ERROR_SUCCESS then begin
            if fCreate then Result := RegCreateKey(hKey, PChar(lpSubKey), phkResult);
        end;
    end else begin
        Result := RegOpenKey(hKey, PChar(lpSubKey), phkResult);
        if Result = ERROR_SUCCESS then begin
            if fCreate then Result := RegCreateKey(hKey, PChar(lpSubKey), phkResult);
        end;
    end;
end;

// 해당 레지스트리 키의 권한을 해제하는 함수
function UnProtectKey(hRKey : Cardinal; lpSubKey : String) : Integer;
var
    SecDes : TSECURITYDESCRIPTOR;
    hRegKey : hKey;
begin
    InitializeSecurityDescriptor(@SecDes, SECURITY_DESCRIPTOR_REVISION);

Result := OpenOrCreateKey(hRKey, lpSubKey, hRegKey);

    if Result = ERROR_SUCCESS then begin
        SetSecurityDescriptorDacl(@SecDes, True, nil, False);
        Result := RegSetKeySecurity(hRegKey, DACL_SECURITY_INFORMATION, @SecDes);
    end;
end;

// 해당 레지스트리 키의 권한을 설정하는 함수
function ProtectKey(hRKey : Cardinal; lpSubKey : String) : Integer;
const
ACL_REVISION = 2;
var
SecDes : TSECURITYDESCRIPTOR;

ACLBuffer: array[1..1024] of Byte;

    ptACL : PACL;
    hRegKey : hKey;
begin
    InitializeSecurityDescriptor(@SecDes, SECURITY_DESCRIPTOR_REVISION);
    ptACL:= @ACLBuffer;
    InitializeAcl(ptACL^, SizeOf(ACLBuffer), ACL_REVISION);

Result := OpenOrCreateKey(hRKey, lpSubKey, hRegKey);

    if Result = ERROR_SUCCESS then begin
        SetSecurityDescriptorDacl(@SecDes, True, ptACL, False);
        Result := RegSetKeySecurity(hRegKey, DACL_SECURITY_INFORMATION, @SecDes);
    end;
end;

PE 구조를 이용해 API `GetProcAddress` 함수 직접 구현하기

과니 — Wed, 23 Apr 2008 00:20:59 +0900

// 과니입니다.
// 이번엔 PE (Portable Executable) 구조체를 이용하여 API 함수인 GetProcAddress함수를 직접 제작해보겠습니다.
// 참고서적은 한빛미디어의 Windows 시스템 실행파일의 구조와 원리입니다.
// 포팅할수있는 부분은 포팅하고 나머진 구현하여 제작하였습니다. (필요없는 부분은 제거도 ㅋㅋㅋ)
// 첨부파일은 PE Format Unit으로 추가해주신 후 사용하시면 됩니다.
// 별로 글제주는 없어서 팁는 주석으로 보충설명하는 식으로 하겠습니다.
// PE 구조를 활용할 수 있는 부분은 DLL내의 Export함수를 모두 뽑아올수있는 것 (물론 프로그램있지만)
// 더 나아가서는 OS Kernel 프로그래밍에도 도움이 됩니다. (아주 열심히 쭉 더 나가면 -_ -a)

uses
..., uPEFormat;

procedure TForm1.Button1Click(Sender: TObject);
const
    SAMPLE_DLL = 'C:\Windows\System32\ntdll.dll';
    SAMPLE_NATIVE_API = 'ZwQueryInformationProcess';
var
    ProcAddr : Pointer;
    handleDll : THandle;
begin

// LoadLibrary로 Dll을 로드하여 프로세스 주소에 매핑
handleDll := LoadLibrary(SAMPLE_DLL);

ProcAddr := MyGetProcAddress(handleDll, SAMPLE_NATIVE_API);

    if not Assigned(ProcAddr) then begin
        ShowMessage('함수가 매핑된 위치가 없습니다.')
    end else begin
        ShowMessage('함수 매핑된 위치 : ' + Format('%p', [ProcAddr]));
    end;

end;

function MyGetProcAddress(hModule : LongWord; pszSymbol : PChar) : Pointer;
type
    TWordArr = array [0..0] of Word;
    PWordArr = ^TWordArr;
    TLongWordArr = array [0..0] of LongWord;
    PLongWordArr = ^TLongWordArr;

var
    // 각 파일 구조체 선언
    pImageBase : PUCHAR;
    pImageDosHeader : PIMAGE_DOS_HEADER;                       // IMAGE_DOS_HEADER
    pImageNtHeaders : PIMAGE_NT_HEADERS;                        // IMAGE_NT_HEADERS
    pImageDataDirectory : PIMAGE_DATA_DIRECTORY;             // IMAGE_DATA_DIRECTORY
    pImageExportDirectory : PIMAGE_EXPORT_DIRECTORY;       // IMAGE_EXPORT_DIRECTORY

dwFuncIndex : LongWord;
pFuncName : PChar;

FnIndex: LongWord;

begin
Result := nil;

pImageBase := PUCHAR(hModule);

    // 매핑되지 않았다면 종료
    // 매핑되지 않았다는 것은 DLL의 주소가 잘못되었다는 것.
    if not Assigned(pImageBase) then Exit;

pImageDosHeader := PIMAGE_DOS_HEADER(pImageBase);

    // PE 포멧 파일인지 확인하여 PE파일이 아니라면 종료한다.
    // PE (Portable Executable) 포멧 파일은 Exe, Dll에 해당한다.
    // PE 구조는 IMAGE_DOS_HEADER, IMAGE_FILE_HEADERM, IMAGE_OPTIONAL_HEADER32 헤더로 구성된다.
    // IMAGE_DOS_SIGNATURE 0x5A4D (23117 : MZ)
    if pImageDosHeader.e_magic <> IMAGE_DOS_SIGNATURE then Exit;

    // e_lfanew : PE 헤더의 시작점을 가리키는 RVA 값이다.
    // 파일이 매핑된 주소의 시점부터 e_lfanew 값을 더하면 IMAGE_NT_HEADERS 가 나온다.
    pImageNtHeaders := PIMAGE_NT_HEADERS(LongInt(pImageBase) + pImageDosHeader.e_lfanew);

    // IMAGE_NT_SIGNATURE 를 확인한다.
    // IMAGE_NT_HEADERS의 시작지점이 $00004550 값인지 확인한다.
    // 0x00004550 (17744 : PE00)
    if pImageNtHeaders.Signature <> IMAGE_NT_SIGNATURE then Exit;

pImageDataDirectory := @pImageNtHeaders.OptionalHeader.DataDirectory[IMAGE_DIRECTORY_ENTRY_EXPORT];

// IMAGE_EXPORT_DIRECTORY : export된 함수들을 담고 있는 구조체이다.
pImageExportDirectory := PIMAGE_EXPORT_DIRECTORY(Cardinal(pImageBase) + pImageDataDirectory.VirtualAddress);

dwFuncIndex := 0;

    // pImageExportDirectory.NumberOfFunctions : DLL 파일 내의 export된 함수의 갯수를 의미한다.
    // 처음부터 갯수만큼 돌면서 검색하려고 하는 함수가 존재하는 지 확인한다.
    while (dwFuncIndex < pImageExportDirectory.NumberOfFunctions - 1) do begin
        // 해당 주소의 함수명을 가져온다.
        pFuncName := PChar(PLongWordArr(Cardinal(pImageExportDirectory.AddressOfNames) +
                             Cardinal(pImageBase))^[dwFuncIndex] + Cardinal(pImageBase));

        // 검색하려고 하는 pszSymbol 함수와
        // DLL에서 검색된 pFuncName 함수를 비교한다.
        if StrLIComp(pszSymbol, pFuncName, Length(pszSymbol)) = 0 then begin
            // AddressOfNameOrdinals 순서수 테이블
            FnIndex := PWORDARR(Cardinal(pImageExportDirectory.AddressOfNameOrdinals) +
                            Cardinal(pImageBase))^[dwFuncIndex];

            // 검색하려는 함수명과 DLL에서 Export된 함수명이 같다면 해당 함수의 주소를 리턴한다.
            Result := Pointer(PLongWordArr(Cardinal(pImageExportDirectory.AddressOfFunctions) +
                          Cardinal(pImageBase))^[FnIndex] + Cardinal(pImageBase));
            Break;
        end;
        // 두 함수가 같지 않으면 Index를 증가해 다음 함수를 검색한다.
        inc(dwFuncIndex);
    end;
end;

델파이에서 포인터 주소값을 문자열로 구할려면

김경진 — Tue, 22 Apr 2008 18:29:57 +0900

팁이라고 말하기 머한 허접한 팁입니다.
후배가 걍 알려달라고해서 알려준건데 걍 혹시나 또 필요하신분 있을까봐 올립니다. ^^
(... 누군가의 팁업로드의 압박이 밀려온다... ㅋㅋ)

procedure TForm1.Button1Click(Sender: TObject);
var
  a : Integer;
  s : String;
begin
  s := Format('%p', [@a]);
  ShowMessage(s);
end;

트리뷰 확장하기

김경진 — Tue, 22 Apr 2008 15:53:37 +0900

트리뷰 확장 팁입니다.

// 트리뷰 확장
procedure TfrmMain.TreeExpand(ANode: TTreeNode);
begin
while Assigned(ANode) do
begin
ANode.Expand(True);
TreeExpand(ANode.getFirstChild);
ANode := ANode.getNextSibling;
end;
end;

// 확장 함수 호출
procedure TfrmMain.btnExpendClick(Sender: TObject);
begin
TreeExpand(TreeView1.Items.GetFirstNode);
end;

* 델마당 질/답 게시판에서 펌한 자료입니다.

WinInet을 이용한 파일 수정 날짜 구하기

김경진 — Mon, 21 Apr 2008 17:18:04 +0900

WinInet을 이용한 서버의 있는 파일의 수정 날짜를 구하는 루틴입니다.
업데이트 유무를 판단할때 유용하게 쓰일수 있습니다.

procedure TForm1.Button1Click(Sender: TObject);
var
hSession : HINTERNET;
hService : HINTERNET;
LastModified : SYSTEMTIME;
FileSize : Longint;
dwSize, Reserved : DWORD;
ft1, ft2 : FILETIME;
t : SYSTEMTIME;
buf : String;
begin
　hSession := InternetOpen( 'MyApp', INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0 );
　if Assigned( hSession ) then
　begin
　　hService := InternetOpenUrl( hSession, PChar(Edit1.Text), nil, 0, 0, 0);
　　if Assigned( hService ) then
　　begin
　　　dwSize := sizeof(LastModified);
　　　Reserved := 0;
　　　HttpQueryInfo(hService, HTTP_QUERY_LAST_MODifIED or HTTP_QUERY_FLAG_SYSTEMTIME,
　　　　　　　　　　　　　　　@LastModified, dwSize, Reserved);
　　　dwSize := sizeof(FileSize);
　　　Reserved := 0;
　　　HttpQueryInfo(hService, HTTP_QUERY_CONTENT_LENGTH or HTTP_QUERY_FLAG_NUMBER,
　　　　　　　　　　　　　　　@FileSize, dwSize, Reserved);
　　　SystemTimeToFileTime( LastModified, ft2 );
　　　FileTimeToLocalFileTime( ft2, ft1 );
　　　FileTimeToSystemTime( ft1, t );
　　　buf := Format('날짜:%4d/%02d/%02d　%2d:%02d:%02d　파일 사이즈:%d',
　　　　　　　　　　[t.wYear, t.wMonth, t.wDay, t.wHour, t.wMinute, t.wSecond, FileSize]);
　　　Memo1.Lines.Add( buf );
　　end;
　　InternetCloseHandle( hService );
　end;
　InternetCloseHandle( hSession );
end;

MsgWaitForMultipleObjects를 이용해 시간 지연시키기

과니 — Sun, 20 Apr 2008 21:05:18 +0900

// MsgWaitForMultipleObjects를 이용해 시간 지연시키기
//
// Sleep과 같은 기능을 하지만 Sleep으로 시간 지연을 하면 메시지 처리를 할 수 없기 때문에 일명'창렉'이 걸리지만,
// 아래 함수는 메시지를 처리하면서 지연을 걸어주기 때문에 창렉이 걸리지 않습니다.
// 사용법도 Sleep이랑 같습니다.
//
// WaitForTimer(1000); <- 1초간 지연을 시킵니다.

procedure WaitForTimer(MilliSeconds : LongInt);
const
        _SECOND = -10000;
var
        lBusy : LongInt;
        hTimer : HWND;
        liDueTime : LARGE_INTEGER;
begin
        hTimer := CreateWaitableTimer(nil, True, 'WaitableTimer');

if hTimer = 0 then Exit;

liDueTime.QuadPart := _SECOND * MilliSeconds;
SetWaitableTimer(hTimer, TLargeInteger(liDueTime), 0, nil, nil, False);

        repeat
                lBusy := MsgWaitForMultipleObjects(1, hTimer, False, INFINITE, QS_ALLINPUT);
                Application.ProcessMessages;
        until lBusy = WAIT_OBJECT_0;

CloseHandle(hTimer);

end;

'GetVersionFromFile'함수로 파일 버전 구하기

과니 — Fri, 18 Apr 2008 13:07:36 +0900

// Windows 유닛의 'GetFileVersionInfo'함수로 일반적으로 파일의 버전을 구하지만

// C:\windows\system32 폴더 안에 보면 'advpack.dll'파일이 있습니다.

// 그중 GetVersionFromFile이라는 함수가 있는데 그 함수로도 파일의 버전을 구하실수가 있습니다.

// DLL 함수 호출 인자는 다음과 같습니다.
// DLL의 함수를 먼저 선언합니다.

        function GetVersionFromFile(lpszFilename : String;
                            var pwMSVer : LongInt;
                            var pwLSVer : LongInt;
                            bVersion : LongInt): LongInt; stdcall; external 'c:\windows\system32\advpack.dll';

procedure TForm1.Button1Click(Sender: TObject);
const
        VER_MAX = $10000;
        TEST_FILE = 'C:\windows\system32\notepad.exe';        // 샘플은 메모장 //
var
        pwMSVer : LongInt;
        pwMShVer, pwMSlVer : Integer;
        pwLSVer : LongInt;
        pwLShVer, pwLSlVer : Integer;
        PwVersion : String;
begin
        pwMSVer := 0;
        pwLSVer := 0;

// advpack.dll에 GetVerionFromFile 함수 호출
GetVersionFromFile(TEST_FILE, pwMSVer, pwLSVer, 1);

        // MSh값과 MSl값 구하기
        pwMShVer := pwMSVer div VER_MAX;
        pwMSlVer := pwMSVer mod VER_MAX;

        // LSh값과 LSl값 구하기
        pwLShVer := pwLSVer div VER_MAX;
        pwLSlVer := pwLSVer mod VER_MAX;

        // 일반 버전 양식으로 변경
        pwVersion := IntToStr(pwMShVer) + '.' + IntToStr(pwMSlVer) + '.' +
                            IntToStr(pwLShVer) + '.' + IntToStr(pwLSlVer);

// 버전 출력
ShowMessage(pwVersion);

end;

// 사실그냥 Windows 유닛에 있는 GetFileVersionInfo 쓰면 되기때문에 쓸일은 없을 것 같습니다.

//
// 이상으로 과니의 많이 쓸일 없는 팁였습니다. ㅋ

API로 파일 생성 후 WriteFile 함수로 강제 개행 하기

과니 — Thu, 17 Apr 2008 13:09:03 +0900

// VCL을 사용하면 쉽게 가능하겠지만 Q&A에서 찾아보니까 없는거 같더라구여...

// API로 파일을 생성해서 강제 개행을 가능하게 해주는 코드입니다.
// 델파이 몇개월 안되는 초보의 코딩이라서 틀린부분이나 리펙토리 해야 할 부분은 알려주세요...

procedure TForm1.Button1Click(Sender: TObject);
const
        SourceFileName = 'C:\SAMPLE_CRLF.txt';
var
        FileHandle : THandle;
begin
        // 파일 생성
        FileHandle := CreateFile(PChar(SourceFileName), GENERIC_WRITE, FILE_SHARE_READ, nil,
                               CREATE_ALWAYS, FILE_ATTRIBUTE_NORMAL, 0);
        try
                if FileHandle <> INVALID_HANDLE_VALUE then begin
                        // 파일이 생성되었다면
                        // 파일에 쓰기
                        WriteFileStr(FileHandle, '1. 가나다라마바사');
                        WriteFileCRLF(FileHandle);                          // 강제 개행함수
                        WriteFileStr(FileHandle, '2. ABCDEFG');
                end;

        finally
                // 파일 닫기
                CloseHandle(FileHandle);
        end;

end;

procedure TForm1.WriteFileCRLF(FileHandle : THandle);
const
        CRLF : array [0..1] of Byte = (13, 10);
var
        NumberOfBytesWrite: LongWord;
begin
        // 다음줄로 이동
        if not WriteFile(FileHandle, CRLF, Sizeof(CRLF), NumberOfBytesWrite, nil) then
                // 에러시 LastError 출력
                ShowMessage(SysErrorMessage(GetLastError()));
end;

procedure TForm1.WriteFileStr(FileHandle : THandle; WriteStr : String);
var
        NumberOfBytesWrite: LongWord;
        WriteMsg : PChar;
begin
        // 문자열 입력
        WriteMsg := Pointer(WriteStr);
        if not WriteFile(FileHandle, WriteMsg^, StrLen(WriteMsg), NumberOfBytesWrite, nil) then
                // 에러시 LastError 출력
                ShowMessage(SysErrorMessage(GetLastError()));
end;

파일 핸들로부터 파일 이름을 얻는 방법.

과니 — Tue, 15 Apr 2008 16:40:47 +0900

// 파일 핸들만 알고 있을 경우 파일 핸들로 파일명을 구하는 방법입니다.
// uses 에 PsAPI unit을 추가해 주세요.
//
// 최중관

procedure TForm1.btnGetFileNameClick(Sender: TObject);
const
        SAMPLE_FILE_NAME = 'C:\WINDOWS\system32\Notepad.exe';
        PAGE_SIZE = $1000;
var
        FileHandle : THandle;
        FileMappingHandle : THandle;
        lpMem : PChar;
        MapFileName : array[0..MAX_PATH - 1] of Char;
begin
        FillChar(MapFileName, Sizeof(MapFileName), #0);

        // 파일 열기
        FileHandle := CreateFile(SAMPLE_FILE_NAME, GENERIC_READ,
                                                FILE_SHARE_READ or FILE_SHARE_WRITE, nil, OPEN_EXISTING,
                                                FILE_ATTRIBUTE_NORMAL, 0);

        if FileHandle <> INVALID_HANDLE_VALUE then begin
                // 파일에 대한 매핑 개체 생성
                FileMappingHandle := CreateFileMapping(FileHandle, nil, PAGE_READONLY, 0, PAGE_SIZE, nil);

                if FileMappingHandle <> INVALID_HANDLE_VALUE then begin
                        // 실제 메모리에 매핑
                        lpMem := MapViewOfFile(FileMappingHandle, FILE_MAP_READ, 0, 0, 0);

                        if lpMem <> '' then begin
                                // 매핑이 완료되었다면 파일의 이름을 얻기
                                GetMappedFileName(GetCurrentProcess,
                                                                     lpMem,
                                                                     MapFileName, Sizeof(MapFileName));

// 결과 출력
ShowMessage(ExtractFileName(MapFileName));

                                // 맵뷰 개체 닫기
                                UnMapViewOfFile(lpMem);
                        end;
                end;

                // 파일 매핑 개체의 핸들을 닫기
                CloseHandle(FileMappingHandle);
        end;

// 파일 핸들을 닫기
CloseHandle(FileHandle);

end;

char* to wchar_t*

김경진 — Mon, 14 Apr 2008 11:12:27 +0900

필요한분들 있을까 해서 올립니다. ^^
즐 코딩 하세요~ ^^

* 출처 : msdn 포럼

LPWSTR ConvertLPCSTRToLPWSTR (char* pCstring)
{
LPWSTR pszOut = NULL;

if (pCstring != NULL)
{
int nInputStrLen = strlen (pCstring);
// Double NULL Termination
int nOutputStrLen = MultiByteToWideChar(CP_ACP, 0, pCstring, nInputStrLen, NULL, 0) + 2;
pszOut = new WCHAR [nOutputStrLen];

if (pszOut)
{
memset (pszOut, 0x00, sizeof (WCHAR)*nOutputStrLen);
MultiByteToWideChar (CP_ACP, 0, pCstring, nInputStrLen, pszOut, nInputStrLen);
}

}

return pszOut;
}

[사용]

char * str = new char[strlen("ASHOK") + 1];

strcpy(str, "ASHOK");

WCHAR * pwStr = ConvertLPCSTRToLPWSTR(str);

//Use this pwStr

......

.....

//delete the wide char pointer.

delete []pwStr;

(Delete, Insert, Home, End, PageUp, PageDown) KeyPress 이벤트 처리가 안될때

김경진 — Fri, 28 Mar 2008 15:52:39 +0900

일단 원인을 정확히 제공 못해드리는 점 사과드립니다.
혹시나 해서 저와 같은 경험이 있으신 분들을 위해 해결 팁만 짧게 적습니다.

리스트 박스에 항목을 넣고 선택한 항목을 Insert 키 밑에 있는 Delete 키를 눌러 삭제하려는데
ListBox컨트롤의 Kepress 이벤트로 연결이 안되더군요. 혹시나 해서 숫자키 아래 있는 Del 키를 눌러보니 이벤트 연결이 되더군요.
일단 바빠서 정확한 원인은 찾지 못했지만 이럴경우 KeyUp에서 처리하니까 이벤트가 연결 되는군요.
머 별 팁도 아니지만 혹시나 해서 참고 삼아 올립니다.

다들 좋은 하루 되시고 홍환민 홈피 많이 자주 이용해 주십시오. ^^

사용자 참여란이란...

홍환민 — Wed, 26 Mar 2008 22:57:54 +0900

안녕하세요? 홍환민입니다.

이 곳은 사용자 참여란 (사용자 참여 게시판)입니다.

기본적인 제 개인 홈페이지고, 제가 작성한 글을 서비스하고 있지만,
아에 사용자가 참여할 수 있는 공간 자체가 존재하기 않기에,
혹시나 하는 마음에 만들었습니다.

강좌나 팁, 혹은 관련된 소식이나.. 저에 대한 요청 사항이나.. 다 허용합니다.
잡다한 얘기들은 주로 자유게시판이 있어서 그쪽에다가 올리셔도 되고요.

강좌/팁란에 올리신 글들은 따로 분류해서 올려드리도록 하겠습니다.

행복한 하루 되십시오.